More after the jump…The setup:

An SWF loads a PHP document which outputs XML:

var url:String = 'some_relative_url.php';
var loader:URLLoader = new URLLoader();
var request:URLRequest = new URLRequest(url);
loader.addEventListener(Event.COMPLETE, loadHandler);
loader.addEventListener(ProgressEvent.PROGRESS, progressHandler);

function progressHandler(event:ProgressEvent):void
{
  trace('Progress: ' + event.bytesLoaded + '/' + event.bytesTotal);
  if(event.bytesLoaded == event.bytesTotal)
    dispatchLoadComplete();
}

function loadHandler(event:Event):void
{
  trace('XML has loaded.');
  var xml:XML = XML(event.target.data);
  trace(xml);
}

//Why am I dispatching that the event is complete? Because this example is from the innards of
//a custom preloader that I created, in which the preloader animation finishes and then the
//preloader announces when the XML is finished loading (Source for the preloader below)
function dispatchLoadComplete():void
{
  dispatchEvent(new Event(Event.COMPLETE));
}

The above code works just fine when loading a file which already has content (for example: loading a pre-existing XML file such as `some_file.xml`. The above code DOES NOT work if the URLLoader is loading a PHP script that outputs the XML, even with correct headers. Here is an example of the PHP script I was loading into Flash:

<?php
$xml = "<?xml version="1.0"?><root><urls><url name="Google" value="http://www.google.com"></url></urls></root>";
file_put_contents('somefile.xml', $xml);

//Output XML for Flash
ob_start();
header('Content-Type: text/xml');
header('Content-Transfer-Encoding: binary');
header("Content-Length: " . filesize('../xml/dynamic.xml') . ";");
//header("filename='dynamic.xml'");
echo $xmlMaker->getDoc();
ob_end_flush();
?>

The above PHP script does load, but the ProgressEvent handler is unable to retrieve the correct file size, and as such only retrieves 0.

Solution
Change the PHP script to redirect to the new file rather than just outputting it, like this:

<?php
$xml = "<?xml version="1.0"?><root><urls><url name="Google" value="http://www.google.com"></url></urls></root>";
file_put_contents('somefile.xml', $xml);

header('Location: somefile.xml');
?>

That works, as the URLLoader’s ProgressEvent is able to retrieve the correct file size.

Source code for my custom preloader

A library MovieClip extends this class in the Flash IDE and contains a TextField (messageTxt) and a MovieClip (progressBar) within it. Example usage below.

package mtm.wl.display
{
	import fl.transitions.easing.Regular;
	import fl.transitions.Tween;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.MovieClip;
	import flash.events.ErrorEvent;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import mtm.net.MultiLoader;
	import mtm.net.MultiURLRequests;
	import mtm.wl.events.WLPreloaderEvent;
	import nl.demonsters.debugger.MonsterDebugger;

	/**
	 * ...
	 * @author Michael T. Moore
	 */
	public class WLPreloader extends MovieClip
	{
		//Stage Instances (must be public)
		public var messageTxt:TextField;
		public var progressBar:MovieClip;

		protected var tween:Tween;

		protected var _loader:*;
		protected var _request:*;
		protected var _completeHandler:Function;
		protected var _target:*;
		protected var preloadComplete:Boolean = false;

		public static const PROGRESS_BAR_MAX_WIDTH:uint = 112;

		private var debugger:MonsterDebugger;

		public function WLPreloader()
		{
			debugger = new MonsterDebugger(this);

			this.alpha = 0;
		}

		public function set message(message:String):void
		{
			messageTxt.text = message;
		}

		public function prepare(loader:*, request:*, completeHandler:Function, msg:String):void
		{
			MonsterDebugger.trace(this, 'prepare()');

			//Check loader type
			if ((loader is URLLoader) || (loader is Loader) || (loader is MultiLoader))
				_loader = loader;
			else
				throw new Error('Argument loader is not correct type. Must be: 1)URLLoader, 2)Loader, or 3)MultiLoader in WLPreloader.prepare()');

			//Check request type
			if (loader is MultiLoader)
			{
				if (request is MultiURLRequests)
					_request = request;
				else
					throw new Error('Loader is of type MultiLoader, but request is not of type MultiURLRequests in WLPreloader.prepare()');
			}
			else if ((loader is URLLoader) || (loader is Loader))
			{
				if (request is URLRequest)
					_request = request;
				else
					throw new Error('Argument request is not correct type. Must be: URLRequest in WLPreloader.prepare()');
			}

			_completeHandler = completeHandler;
			message = msg;
			init();
		}

		protected function init():void
		{
			MonsterDebugger.trace(this, 'init()');

			resetProgressBar();
			preloadComplete = false;
			if (_loader is URLLoader)
			{
				MonsterDebugger.trace(this, '_loader is URLLoader');
				_loader.addEventListener(Event.COMPLETE, getEventData);
				_loader.addEventListener(IOErrorEvent.IO_ERROR, catchError);
				_loader.addEventListener(ProgressEvent.PROGRESS, increment);
				_loader.load(_request);
			}
			else if (_loader is Loader)
			{
				MonsterDebugger.trace(this, '_loader is Loader');
				_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, getEventData);
				_loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, catchError);
				_loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, increment);
				_loader.load(_request);
			}
			else if (_loader is MultiLoader)
			{
				MonsterDebugger.trace(this, '_loader is MultiLoader');
				_loader.addEventListener(Event.COMPLETE, getEventData);
				_loader.addEventListener(IOErrorEvent.IO_ERROR, catchError);
				_loader.addEventListener(ProgressEvent.PROGRESS, increment);
				_loader.load(_request);
			}
		}

		protected function resetProgressBar():void { progressBar.width = 0; }

		public static function percentage(loaded:uint, total:uint):uint
		{
			return Math.round(loaded / (total / PROGRESS_BAR_MAX_WIDTH));
		}

		public function increment(event:ProgressEvent):void
		{
			progressBar.width = percentage(ProgressEvent(event).bytesLoaded, ProgressEvent(event).bytesTotal);
			MonsterDebugger.trace(this, 'Progress: ' + event.bytesLoaded + '/' + event.bytesTotal);
			if (progressBar.width == PROGRESS_BAR_MAX_WIDTH)
			{
				MonsterDebugger.trace(this, 'progressBar.width == PROGRESS_BAR_MAX_WIDTH');
				addEventListener(Event.ENTER_FRAME, check);
			}
		}

		protected function getEventData(event:Event):void
		{
			MonsterDebugger.trace(this, 'getEventData()');
			_target = null;

			if (event.target is URLLoader)
				_target = URLLoader(event.target);
			else if (event.target is LoaderInfo)
				_target = LoaderInfo(event.target);
			else if (event.target is MultiLoader)
				_target = MultiLoader(event.target);

			MonsterDebugger.trace(this, '_target = ' + _target);

			preloadComplete = true;
		}

		protected function check(event:Event):void
		{
			if (preloadComplete)
			{
				MonsterDebugger.trace(this, 'preloadComplete == true');
				removeEventListener(Event.ENTER_FRAME, check);
				dispatchPreloadCompleteEvent();
			}
		}

		protected function dispatchPreloadCompleteEvent():void
		{
			MonsterDebugger.trace(this, 'dispatchPreloadCompleteEvent()');
			_completeHandler(new Event(Event.COMPLETE));
			//dispatchEvent(new Event(Event.COMPLETE));
		}

		public function show(fade = true):void
		{
			(fade) ? tween = new Tween(this, "alpha", Regular.easeIn, 0, 1, 5) : this.alpha = 1;
		}

		public function hide(fade = true):void
		{
			(fade) ? tween = new Tween(this, "alpha", Regular.easeIn, 1, 0, 5) : this.alpha = 0;
		}

		protected function catchError(event:ErrorEvent):void
		{
			if (event is IOErrorEvent)
				throw new Error('IOErrorEvent caught in ' + this + ': ' + event.text);
			else
				throw new Error('Error caught in ' + this + ': ' + event.text);
		}

		public function get target():*
		{
			return _target;
		}

	}

}

Use the preloader like this:

preloader.prepare(new URLLoader(), new URLRequest('someurl.php'), completeHandler, 'Loading Something');
function completeHandler(event:Event):void
{
  var loader:URLLoader = URLLoader(preloader.target);
}

If you are curious about my MultiLoader and MultiURLRequests classes, just let me know and I’ll post them.

//Create an array to hold Objects representing images
var images:Array = new Array();

//Create some objects representing images
images[0] = new Object();
images[0].filename = 'cat.jpg';
images[0].orderNum = 0;

images[1] = new Object();
images[1].filename = 'dog.jpg';
images[1].orderNum = 2;

images[2] = new Object();
images[2].filename = 'dragon.jpg';
images[2].orderNum = 1;

display(images);
/*
Contents of images:
images[0].orderNum = 0
images[1].orderNum = 2
images[2].orderNum = 1
*/

//Sort the images array by the "orderNum" property of each Object value
images.sortOn("orderNum");

display(images);
/*
Contents of images:
images[0].orderNum = 0
images[1].orderNum = 1
images[2].orderNum = 2
*/

function display(images:Array):void
{
  trace('Contents of images:');
  for(var i:int = 0; i < images.length; i++)
  {
    trace('images[' + i + '].orderNum = ' + images[i].orderNum);
  }
}

Where’s your font file?
Find the location of the truetype (TTF) file for the font you are going to embed. I am using Futura Std Book, and it’s truetype file is located at C:\Windows\Fonts\FuturaStd-Book.ttf.

The code
Add the following code to your AS3 class. I added mine alongside my class property definitions:

[Embed(source="C:\WINDOWS\Fonts\FuturaStd-Book.ttf", fontFamily="Futura Std Book")]

Note: The fontFamily variable in the above code must be the family name for your font. So, for example, I had to use “Futura Std Book”. I could not have chosen something custom like “Futura” or “futurefont” or “bacon”. Mmmm… bacon…

This was a bit of a pain because the font file did not have spaces (“FuturaStd-Book.ttf”), but if you are on Windows, you can double-click your TTF file and it will see the “Font name” that you need to use. Here’s a screenshot from my computer:

Setup the TextFormat instance

//Imports
import flash.text.TextFormat;
import flash.text.AntiAliasType;
import flash.text.TextField;

//Declare your TextFormat instance
protected var format:TextFormat = new TextFormat();

//Setup the font with your TextFormat instance
//This must be exactly what you set as "fontFamily" in the Embed code
format.font = "Futura Std Book";
format.embedFonts = true;
format.antiAliasType = AntiAliasType.ADVANCED;
format.size = 14;

var textField:TextField = new TextField();
textField.setTextFormat(format);
textField.text = 'Awesome!';

I have a primary SWF called top.swf that loads an XML file with a list of URLs for other SWF files that will be loaded as sub-SWFs in top.swf.

The XML file loads fine (it is located in a directory below top.swf). The issue is in the loading of the sub-SWFs (all located in a directory below top.swf called swf. To avoid this error/security violation, add the following line to the constructor of each of your sub-SWF’s Document class:

Security.allowDomain('*');

You will need to add the following import to each of the Document classes as well:

import flash.system.Security;

Note: You must have the Flash Debug Player installed to catch Security Sandbox violations in your browser.

When using flash.net.URLLoader to load external XML data and working on the local server, if the XML is updated between compiles, Flash CS3 will keep loading the previous version. In my case I have a PHP file that is called and the PHP file outputs XML.

To prevent the cache issue:

Append a randomly generated number to the URL string that points to the XML file (or, in my case, the PHP file).

var xmlUrl:String = 'some_url.php';
var randomNumber:int = Math.round(Math.random()*100000000);
xmlUrl += '?prevent_cache=' + randomNumber;

var functionsArray:Array = new Array();

register(testA);
register(testB);

for each(var f:Function in functionsArray)
{
	f();
}

function register(f:Function):void
{
  functionsArray.push(f);
}

function testA():void
{
  trace('testA() called.');
}

function testB():void
{
  trace('testB() called.');
}

Edit the winfileextension and macfileextension attributes to include inc.

Before:

<documenttype id="PHP_MySQL" servermodel="PHP MySQL" internaltype="Dynamic" winfileextension="php,php3,php4,php5" macfileextension="php,php3,php4,php5" file="Default.php" writebyteordermark="false">

After:

<documenttype id="PHP_MySQL" servermodel="PHP MySQL" internaltype="Dynamic" winfileextension="php,php3,php4,php5,inc" macfileextension="php,php3,php4,php5,inc" file="Default.php" writebyteordermark="false">

Save the file and restart Dreamweaver. Worked for me! Thanks to John T on superuser for this solution.

I will document my discoveries in a series of posts, starting with this one.

The post_max_size setting in php.ini:

Per Matthew Flaschen’s answer to my question “What exactly does it mean when $_FILES is empty?”, it is most likely due to the size of the to-be-uploaded-file exceeding what post_max_size is set to in php.ini. This was the problem when I tried uploading a 17MB TIFF image file to test what would happen on the user’s end. Specifically, the $_FILES superglobal (and $_POST) were returning empty. Had I read through this PHP manual page, I would have figured that out (scroll down to post_max_size in that link).

So, now I check if $_POST or $_FILES are empty with:

if(empty($_POST) || empty($_FILES))
{
    //Do some friendly error-checking here
}

As of right now, I am displaying an error recommending that the user check the size of their file. In the current project I am working on, it is very likely that the client is attempting to upload original high-resolution image files (which are typically well over the 2M default upload_max_filesize and most definitely well over the 8M default post_max_size in php.ini).

unzip

for the first time in Linux. I had to apt-get install unzip zip first.

I am installing WordPress 2.9.2 on my development server, which means I downloaded the WordPress ZIP file and FTPed it to my server. I found this tutorial which led me to the proper command to unzip WordPress into a specified directory:

unzip wordpress-2.9.2.zip -d /var/www

This gave me

/var/www/wordpress

, which I renamed to

/var/www/miketmoore

by using

mv /var/www/wordpress /var/www/miketmoore

.

Yay for zipping!

This is my first direct experience with Linux. I also grabbed a copy of Scott Granneman’s Linux Phrasebook. It’s a great book for introductory shell commands. I also have needed to consult various internet resources for some things (mainly with learning about Linux permissions).

The primary reason that I wanted an actual server in the first place (rather than stick with my previous setup of WAMPServer) was to learn more about what my hosting service deals with and to understand security risks better. In the week that I’ve had the server set up I have learned a great deal about how permissions settings on files and directories affect public access. In addition, I have learned some basic administration for vsftpd (FTP server I installed). Specifically, in editing `vsftpd.conf`, which is located at `/etc/vsftpd.conf`.